Bonjour, qui peut me donner la formule pour calculer le nombre de jours, ou mois entre la datte actuelle la date d'anniversaire par exemple?

Cette fonction personnalisée me semble bien !? DateDifference

Bonjour, Pour calculer le nombre de jours c'est assez simple au final, car c'est le mode de calcul natif de FileMaker, il suffit de convertir les deux dates en nombre (comme ceci "ObtenirNombre(table::rubrique_date)") puis simplement de les soustraire pour obtenir la différence en nombre de jours ;)

Et aussi sans convertir en nombre comme ceci : Definir ( [ d_a = Obtenir ( DateActuelle ) ; d_j = MaRubriqueDate ] ; d_a - d_j & " jours" ) Le tout dans une nouvelle rubrique de type Calcul non mémorisée.

Ce que je cherche à faire exactement, c'est trouver le nombre de jours et du mois dans une date. Exemple: entre la date actuelle et la date d'embauche il s'est écoulé combien de mois et de jour depuis l'engagement.

En supposant que l'on néglige les différentes longueurs des mois et qu'on fait ce calcul le 15 février pour quelqu'un embauché le 10 décembre, le temps écoulé sera de 2 mois et 5 jours. C'est bien ça ? Il faut donc calculer le nombre de mois d'une part et comparer le nombre de jour ensuite. On peut utiliser les fonctions Année(), Mois() et Jour() et les combiner pour arriver au résultat souhaité. Et si on ne veut pas le faire soi-même, la fonction proposée par Homer est parfaite pour ça !

Oui MagalieJ, c'est exactement ce que je cherche à faire!

Kenshiro Savez-vous comment récupérer et utiliser une fonction personnalisée ?

Que tout ceci est compliqué. ObtenirDate ( datefin - dateDebut + 1 ) Donne une date avec le nombre de jours, de mois et d’années. On ajoute 1 parce que si quelque chose se passe sur une journée on dit 1 jour, pas 0. (C’est pourquoi il n’y a pas d’année zéro)

En complément de ma réponse ci-dessus, il ne reste plus qu'à extraire les jours, mois et années avec les fonctions éponymes.

Ce site est optimisé pour être consulté depuis un navigateur moderne dans lequel JavaScript est activé.

calculer le nombre de jours entre deux dates

bobino

En fait je n'ai que partagé un truc pour pour présenter les calculs et faciliter le copier-coller sur le forum. Je n'ai fait que reprendre le dernier calcul du file de discussion au moment où je suis intervenu. Le mérite ne me reviens certainement pas.

@Kenshiro En fait je profite de l'occasion pour mentionner qu'il devrait t'être possible, en survolant la réponse de ton choix et en cliquant sur "…" de sélectionner une réponse comme étant la "meilleure" réponse.

Même si on reconnaît tous qu'il y a différentes façons de parvenir à ses fins, les lecteurs qui nous suivront apprécieront sans doute l'économie de temps de pouvoir identifier rapidement la réponse que tu estime correspondre le mieux à ce que tu recherchais.

Kenshiro

bobino, vraiment merci pour ta collaboration ainsi que toutes les personnes présente qui on réagit à ma demande, oui j'ai juste fait copier coller pour l'insérer à ma cellule.

FabriceN

Voici ma proposition qui gère tous les cas je pense (sauf celui où la date 2 est inférieure ou égale à la date 1)

let ([

// paramètres

d1 = date ( 1 ; 10 ; 2022 );

d2 = get ( CurrentDate ) ;

d = GetAsDate ( d2 - d1 + 1 ) ;

j = day ( d ) ;

j = case ( j ; j & " jour" ) & case ( j > 1 ; "s" ) ;

m = Month ( d ) -1 ;

m = case ( m ; m & " mois" ) ;

a = year ( d ) -1 ;

a = case ( a ; a & " an" ) & case ( a > 1 ; "s" ) ;

r = substitute ( list ( a ; m ; j ) ; ¶ ; ", " ) ;

// remplacement de la dernière virgule par "et"

resultat = Replace ( r ; Position ( r ; "," ; 99999 ; -1 ) ; 1 ; " et" )

];

resultat

)

JeremieGimenez

FabriceN

Pour un écart du 15/12/2022 au 15/12/2023, tu obtiens «1 an et 1 jour», je suis bien d'accord, mais du 15/12/2022 au 14/12/2023, tu obtiens «11 mois et 31 jours» alors que ça devrait être «1 an (et 0 jour)»

NB : j'ai passé 2 heures sur la formule, notamment à cause de l'anniversaire et de sa veille ! 😅

JeremieGimenez

Et voici mon approche, par étapes et sans aucune condition : (je ne gère pas non plus le cas Date2<Date1)

Definir (
[
a = Date ( 12 ; 15 ; 2022 )               // Date 1
; b = Date ( 2 ; 10 ; 2025 ) + 1          // Date 2 (incluse grâce au +1)
; c = b - a
; d = Annee ( c + 1 ) - 1
; e = Date ( Mois ( a ) ; Jour ( a ) ; Annee ( a ) + d )
; f = b - e
; g = Mois ( f + 1 ) - 1
; h = Date ( Mois ( e ) + g ; Jour ( e ) ; Annee ( e ) )
; i = b - h
] ;

"Différence totale en jours : " & c
& "¶¶Années entières : " & d
& "¶¶Date de fin des années entières : " & e
& "¶¶Nouvelle différence en jours : " & f
& "¶¶Mois entiers : " & g
& "¶¶Date de fin des mois entiers : " & h
& "¶¶Dernière différence en jours : " & i
& "¶¶Phrase complète : " & d & " année(s), " & g & " mois et " & i & " jour(s)"

)

Le plus difficile a été de faire fonctionner ça la veille de l'anniversaire ET le jour d'anniversaire, mais ça marche :

Différence totale en jours : 789
Années entières : 2
Date de fin des années entières : 15/12/2024
Nouvelle différence en jours : 58
Mois entiers : 1
Date de fin des mois entiers : 15/01/2025
Dernière différence en jours : 27
Phrase complète : 2 année(s), 1 mois et 27 jour(s)

Evidemment, seule la phrase complète, en dernière ligne, nous intéresse. Le reste n'est que didactique.

Kenshiro

JeremieGimenez 🤣🤣😂😅

JeremieGimenez

Jacques_Rechain

Je continue mes tests, je pars toujours du 15/12/2022 :

pour obtenir un résultat de «1 jour», il faut attendre le 17/12/2022,
au 14/12/2023, tu as «11 mois et 29 jours», alors que ça devrait être 1 an tout rond (il est marrant, ce mois de novembre, il compte 29 jours avec ta formule et 31 avec celle de Fabrice 😉)
au 14/12/2024, tu as «1 an, 11 mois et 30 jours», au lieu de 2 ans (là par contre, novembre fait bien 30 jours)

Voilà donc un sujet d'apparence anodine et qui nous aura tous faire marner 😆

Jacques_Rechain

JeremieGimenez J'ai ajouté le " + 1" de Fabrice, la notion de date de début supérieure à celle de fin et simplifié la gestion des ", " et " et ". Ça semble maintenant ok.

Definir ( [ d1 = Ecart_Dates::Date_1 ; d2 = Ecart_Dates::Date_2 ; 
d = ObtenirDate ( Si ( d1 > d2 ; d1 - d2 ; d2 - d1 ) ) + 1 ;
j = Jour ( d ) - 1 ; m = Mois ( d ) - 1 ; a = Annee ( d ) - 1 ;
n = Si ( j > 0 ; 1 ) + Si ( m > 0 ; 1 ) + Si ( a > 0 ; 1 ) ] ;

Si ( a > 0 ; a & " an" & Si ( a > 1 ; "s" ) 
& Cas ( n > 2 ; ", " ; n > 1 ; " et " ) )

& Si ( m > 0 ; m & " mois" ) 

& Si ( j > 0 ; Si ( n > 1  ; " et " )
& j & " jour" & Si ( j > 1 ; "s" ) )

 )

Matessias

De mon côté, lors de mes débuts en FM, j'avais à définir l'ancienneté d'un employé à partir de sa date d'embauche à la date du jour. J'ai juste joué sur les rubriques, ignorant toute cette panoplie de raisonnement !

NB : J'envoie deux captures écran qui ne s'affichent pas !

JeremieGimenez

Matessias Pour l'instant, on ne peut pas trop envoyer des images.

(Dans un sens, cela nous force à publier du bon contenu textuel, plus facile à indexer et à référencer par les moteurs)

JeremieGimenez

Jacques_Rechain

Par rapport à @FabriceN et moi, tu gères le cas d2<d1, et en toute simplicité en plus, c'est chouette ! 👏

Par contre :

du 15 au 15 (même mois, même année), on obtient «?» au lieu de 1 jour
du 15 au 15 N+1, on obtient «1 an»
du 15 au 15 N+2, on obtient «2 ans et 1 jour»
du 15 au 15 N+3, on obtient «3 ans et 1 jour»
du 15 au 15 N+4, on obtient «4 an»

J'ai pensé un moment que cette variation était due aux années bissextiles, mais en fait non…

Et ma formule avec les années pleines et les mois pleins, qu'en penses-tu ?

Jacques_Rechain

JeremieGimenez Alors pour comparaison de la même date, j'ai ajouté une condition.

Pour l'écart "du 15 au 15 N+2, on obtient «2 ans et 1 jour»" cela me semble normal puisqu'il y a 29 jours en février 2024. J'ai souvenir, enfant, d'une dame qui était née un 29 février, et ce me semblait normal de ne lui fêter son anniversaire que tout les 4 ans !!!

Definir ( [ d1 = Ecart_Dates::Date_1 ; d2 = Ecart_Dates::Date_2 ; 
d = ObtenirDate ( Si ( d1 > d2 ; d1 - d2 ; d2 - d1 ) ) + 1 ;
j = Jour ( d ) - 1 ; m = Mois ( d ) - 1 ; a = Annee ( d ) - 1 ;
n = Si ( j > 0 ; 1 ) + Si ( m > 0 ; 1 ) + Si ( a > 0 ; 1 ) ] ;
Si ( d ≠ "?" ;

Si ( a > 0 ; a & " an" & Si ( a > 1 ; "s" ) 
& Cas ( n > 2 ; ", " ; n > 1 ; " et " ) )

& Si ( m > 0 ; m & " mois" ) 

& Si ( j > 0 ; Si ( n > 1  ; " et " )
& j & " jour" & Si ( j > 1 ; "s" ) )

; "0 jour" )

 )

sparent

Je suis en retard, mais le problème est intéressant. De plus j'ai trouvé une solution qui retourne le bon résultat avec des dates quelconques. date1 > date2, date1 = date2, date1 < date2

Objectif : calculer le nombre d'années, de mois et de jours de travail d'un employé entre la date d'embauche et une date de fin.

À mon avis, la technique de la période reportée, proposée par Fabrice, ne peut pas fonctionner. Elle calcule le nombre de jours entre deux dates et reporte ce nombre de jours sur une autre période. Si la période initiale inclut une année bissextile et que la période reportée n'en inclut pas, on aura un décalage.

Ma solution est une fonction personnalisée. Elle utilise la récursivité. Elle déplace la date de début par bloc mensuel tant et aussi longtemps que la date (date d'étape) est à l'intérieur des limites. Lorsqu'elle a trouvé le nombre de mois, elle utilise la date d'étape pour calculer le nombre de jours restants.

Exemple 1 : Un employé qui a travaillé du 15 décembre 2022 au 15 décembre 2022 à travailler 1 jour.

Exemple 2 : Un employé qui a travaillé du 15 décembre 2022 au 14 janvier 2023 à travailler 1 mois.

Exemple 2 : Un employé qui a travaillé du 15 décembre 2022 au 15 décembre 2023 à travailler 1 an et 1 jour

Exemple 3 : Un employé qui a terminé son emploi le 15 décembre 2023 et avait commencé à travailler le 15 décembre 2022 à travailler 1 an, 0 mois et 1 jour

HTH

/**

uDate_00ObtenirDecompteAMJ ( date1 ; date2 )

Retourne une liste comportant le décompte des années, des mois et des jours inclus entre les 2 dates reçues. Les dates sont incluses.
Retourne une liste 3 valeurs. 
Les dates peuvent être quelconques, mais doivent être valides.

Fonction privée publique

**/

///date2 = Date ( 12 ; 15 ; 2022 ) 
///date1 = Date ( 12 ; 15 ; 2023 ) 


TantQue ([ 

vDate01 = ObtenirDate ( date1 ) ;
vDate02 = ObtenirDate ( date2 ) ;

vDateDepart = Si ( vDate01 > vDate02 ; vDate02 ;  vDate01 ) ;
vDateFin = Si ( vDate01 > vDate02 ; vDate01 ;  vDate02 ) ;
vEstDansLimite = 1 ;	
vDecalage = 0 

]; 

vEstDansLimite

;[

vDecalage = vDecalage + 1 ; 
vDateTest = Date ( Mois ( vDateDepart ) + vDecalage ; Jour ( vDateDepart ) - 1 ; Annee ( vDateDepart ) ) ;
vDateEtape = Date ( Mois ( vDateDepart ) + ( vDecalage-1 ) ; Jour ( vDateDepart ) - 1 ; Annee ( vDateDepart ) ) ;
vEstDansLimite = vDateTest ≤ vDateFin 

];

Liste ( Div ( vDecalage-1 ; 12 ) ; Mod ( vDecalage-1 ; 12 ) ; vDateFin-vDateEtape )


)

MagalieJ

sparent Très élégante solution ! Ce n'est pas tout à fait ce que j'avais en tête (et que je n'ai pas pris le temps d'écrire), mais le résultat est parfait !

Reste à Kenshiro à découvrir les fonctions personnalisées… Un peu de littérature sur le sujet https://help.claris.com/fr/pro-help/content/using-custom-functions.html (déjà cité par Homer ci-dessus, mais quand on aime… 😉)

Kenshiro

Qui aurait un bon lien pour apprendre et comprendre à faire les variables sur filemaker!

FabriceN

Kenshiro

Ce serait bien si sur ce nouveau forum tout beau tout propre on prenait l'habitude d'ouvrir un nouveau fil de discussion pour parler d'un nouveau sujet.

Matessias

Je serai bien preneur de ce "bon lien" !

En tous cas, comme en toute chose, il ne peut s'agir que de la pratique.

L'idéal serait que l'on explique "bien" ce qu'est une variable !

De ma part, je ne connais l'utilisation de variables que dans le cadre de scripts : je dirai que lorsqu'on a besoin d'utiliser des données, il faut commencer par les stocker ; l'utilisation ne sera que facilitée car il suffit de faire appel au "nom" qu'on a donné au stockage au lieu de faire appel, à chaque fois, aux données elles-mêmes !

Alors, il n'y a plus qu'à faire un tour dans un script pour concrétiser !

« Page précédente